# This is a demo script illustrating how to write a service with detector zones using the AD unit's built-in stimuli. Adjust the SETLIGHT functions with the LT screen coordinates if 
# using the LT unit.

# When you place the 'fake fish' over the any of the colours when presented various consquences will occur.

# This is a sample script that illustrates how zanscript can be written to run an experiment and deliver some example data.  Zantiks Ltd cannot guarantee
# this is how you want to run your experiments, this script is offered only to demonstrate the capabilities of the system and assist you in learning how
# to script for your research.


DEFINE SCROLLTIME 5
DEFINE WAIT_TIME 6
DEFINE ITI 2
DEFINE TRIALS 7

# define the animal model tracking requirments (dependent on animal size)
SET(TARGET_SIZE,15) 
SET(DETECTOR_THRESHOLD,5) 
 
# define auto reference tracking requirements 
SET(AUTOREF_MODE,MOVEMENT)		            
SET(AUTOREF_TIMEOUT,5)    

# set light stimuli coordinates on the screen
SETLIGHT(LIGHT1,SQUARE,194.5,18.2,21) 
SETLIGHT(LIGHT2,SQUARE,194.5,45.6,21) 
SETLIGHT(LIGHT3,SQUARE,194.5,73,21) 
SETLIGHT(LIGHT4,SQUARE,194.5,100.4,21) 
SETLIGHT(LIGHT5,SQUARE,194.5,127.8,21) 
SETLIGHT(LIGHT6,SQUARE,37,72,21)

SETLIGHT(LIGHT8,SPRITE,103,73,0)
LOAD(SPRITE_IMAGE,"8:danio_small") 

# load detector asset
LOAD(ZONES,"5_CHOICE") 
	
	
ACTION MAIN

	AUTOREFERENCE()
	INVOKE(ZONES_TEST,TRIALS) 

COMPLETE


ACTION ZONES_TEST

	LIGHTS(LIGHT1,MAGENTA)
	LIGHTS(LIGHT2,BLUE)
	LIGHTS(LIGHT3,GREEN)
	LIGHTS(LIGHT4,YELLOW)
	LIGHTS(LIGHT5,CYAN)
	LIGHTS(LIGHT6,RED)
	
	DETECTOR(DETECTOR1,DETECTOR1_TRIGGERED)
	DETECTOR(DETECTOR2,DETECTOR2_TRIGGERED)
	DETECTOR(DETECTOR3,DETECTOR3_TRIGGERED)
	DETECTOR(DETECTOR4,DETECTOR4_TRIGGERED)
	DETECTOR(DETECTOR5,DETECTOR5_TRIGGERED)
	DETECTOR(DETECTOR6,DETECTOR6_TRIGGERED)
	
	WAIT(WAIT_TIME)
	LIGHTS(ALL,OFF)
	WAIT(ITI)
	
COMPLETE


ACTION DETECTOR1_TRIGGERED

	LIGHTS(ALL,OFF) 
 	LIGHTS(LIGHT8,ON) 
 	PANLIGHT(LIGHT8,250,73,SCROLLTIME)
 
 	WAIT(WAIT_TIME) 
 	LIGHTS(LIGHT8,OFF) 
 	WAIT(WAIT_TIME) 
 
 	SETLIGHT(LIGHT8,SPRITE,103,73,0)

COMPLETE


ACTION DETECTOR2_TRIGGERED

	LIGHTS(ALL,OFF)
	WAIT(WAIT_TIME)

COMPLETE


ACTION DETECTOR3_TRIGGERED

	LIGHTS(ALL,OFF)
	LIGHTS(LIGHT16,BLUE)

	WAIT(WAIT_TIME)
	LIGHTS(ALL,OFF)

COMPLETE


ACTION DETECTOR4_TRIGGERED

	LIGHTS(ALL,OFF)
	FEEDER(1)
	WAIT(WAIT_TIME)

COMPLETE


ACTION DETECTOR5_TRIGGERED

	LIGHTS(ALL,OFF)
	SET(VOLTAGE_LEVEL,9000) 
 	WAIT(ITI) 
 
 	SET(VOLTAGE4,70) 
 	WAIT(ITI) 

COMPLETE


ACTION DETECTOR6_TRIGGERED

	LIGHTS(ALL,OFF)
	LIGHTS(LIGHT6,GREEN)
	WAIT(WAIT_TIME)
	LIGHTS(ALL,OFF)

COMPLETE